stdlib/arith-each.tl


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103

;; Copyright 2021-2024
;; Kaz Kylheku <kaz@kylheku.com>
;; Vancouver, Canada
;; All rights reserved.
;;
;; Redistribution and use in source and binary forms, with or without
;; modification, are permitted provided that the following conditions are met:
;;
;; 1. Redistributions of source code must retain the above copyright notice,
;;    this list of conditions and the following disclaimer.
;;
;; 2. Redistributions in binary form must reproduce the above copyright notice,
;;    this list of conditions and the following disclaimer in the documentation
;;    and/or other materials provided with the distribution.
;;
;; THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS"
;; AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
;; IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
;; ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDER OR CONTRIBUTORS BE
;; LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
;; CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
;; SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
;; INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
;; CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
;; ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
;; POSSIBILITY OF SUCH DAMAGE.

(defun sys:vars-check (form vars)
  (unless (listp vars)
    (compile-error form "~s is expected to be variable binding syntax" vars))
  (whenlet ((bad (find-if [notf consp] vars)))
    (compile-error form "~s isn't a var-initform pair" bad)))

(defmacro sys:arith-each (fn iv short-circ vars . body)
  (let* ((gens (mapcar (ret (gensym)) vars))
         (syms [mapcar car vars])
         (accum (gensym)))
    (if (null vars)
      iv
      ^(let* (,*(mapcar (ret ^(,@1 (iter-begin ,@2))) gens syms)
               (,accum ,iv))
         (block nil
           (sys:for-op ()
             ((and ,*(mapcar (op list 'iter-more) gens)
                   ,*(cond
                       ((eq t short-circ) ^(,accum))
                       ((null short-circ) ^((null ,accum)))
                       ((eq '+ short-circ) ^((nzerop ,accum)))))
              ,accum)
             (,*(mapcar (ret ^(sys:setq ,@1 (iter-step ,@1))) gens))
             ,*(mapcar (ret ^(sys:setq ,@1 (iter-item ,@2))) syms gens)
             (set ,accum ,(cond
                            ((consp fn) ^(,(car fn) ,accum (progn ,*body)))
                            (fn ^(,fn (progn ,*body)))
                            (t ^(progn ,*body))))))))))

(defmacro sum-each (:form f vars . body)
  (sys:vars-check f vars)
  ^(let ,vars
     (block nil
       (sys:arith-each (+) 0 : ,vars ,*body))))

(defmacro sum-each* (:form f vars . body)
  (sys:vars-check f vars)
  ^(let* ,vars
     (block nil
       (sys:arith-each (+) 0 : ,vars ,*body))))

(defmacro mul-each (:form f vars . body)
  (sys:vars-check f vars)
  ^(let ,vars
     (block nil
       (sys:arith-each (*) 1 + ,vars ,*body))))

(defmacro mul-each* (:form f vars . body)
  (sys:vars-check f vars)
  ^(let* ,vars
     (block nil
       (sys:arith-each (*) 1 + ,vars ,*body))))

(defmacro each-true (:form f vars . body)
  (sys:vars-check f vars)
  ^(let* ,vars
     (block nil
       (sys:arith-each nil t t ,vars ,*body))))

(defmacro some-true (:form f vars . body)
  (sys:vars-check f vars)
  ^(let* ,vars
     (block nil
       (sys:arith-each nil nil nil ,vars ,*body))))

(defmacro each-false (:form f vars . body)
  (sys:vars-check f vars)
  ^(let* ,vars
     (block nil
       (sys:arith-each not t t ,vars ,*body))))

(defmacro some-false (:form f vars . body)
  (sys:vars-check f vars)
  ^(let* ,vars
     (block nil
       (sys:arith-each not nil nil ,vars ,*body))))