genman.txr


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53

@# This requires the man2html which was originally known as vh-man2html
@# and is now part of manutils.
@# See here: http://primates.ximian.com/~flucifredi/man/
@# It does not work with that other man2html written in Perl.
@(deffilter month_name
  ("01" "Jan") ("02" "Feb") ("03" "Mar") ("04" "Apr")
  ("05" "May") ("06" "Jun") ("07" "Jul") ("08" "Aug")
  ("09" "Sep") ("10" "Oct") ("11" "Nov") ("12" "Dec"))
Content-type: text/html
@(skip 15)
<H1>TXR</H1>
@(skip)Updated: @YEAR-@MONTH-@DAY<BR><A HREF="#index">Index</A>
@(collect)
@PREAMBLE
@(until)
txr - text processing language @(skip)
@(end)
@(all)
txr - text processing language @VERSION
@  (and)
@  (collect)
@BODY
@  (until)
<HR>
<A NAME="index">&nbsp;</A><H2>Index</H2>
@  (end)
@(end)
<HR>
@(collect)
@TOC
@(until)
This document was created by
@(end)
@(output)
<HTML>
<FONT FACE="courier">
<HEAD><TITLE>Manpage for TXR @VERSION</TITLE>
</HEAD><BODY>
<H2>Manpage for <A HREF="#lbAB">TXR </a>@VERSION</H2>
<H2>@{MONTH :filter month_name} @DAY, @YEAR</H2>
@(repeat)
@TOC
@(end)
@(repeat)
@PREAMBLE
@(first)
@(end)
@(repeat)
@BODY
@(end)
</BODY>
</HTML>
@(end)