1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
|
# id.awk --- implement id in awk
#
# Requires user and group library functions
#
# Arnold Robbins, arnold@skeeve.com, Public Domain
# May 1993
# Revised February 1996
# Revised May 2014
# output is:
# uid=12(foo) euid=34(bar) gid=3(baz) \
# egid=5(blat) groups=9(nine),2(two),1(one)
BEGIN \
{
uid = PROCINFO["uid"]
euid = PROCINFO["euid"]
gid = PROCINFO["gid"]
egid = PROCINFO["egid"]
printf("uid=%d", uid)
pw = getpwuid(uid)
if (pw != "")
pr_first_field(pw)
if (euid != uid) {
printf(" euid=%d", euid)
pw = getpwuid(euid)
if (pw != "")
pr_first_field(pw)
}
printf(" gid=%d", gid)
pw = getgrgid(gid)
if (pw != "")
pr_first_field(pw)
if (egid != gid) {
printf(" egid=%d", egid)
pw = getgrgid(egid)
if (pw != "")
pr_first_field(pw)
}
for (i = 1; ("group" i) in PROCINFO; i++) {
if (i == 1)
printf(" groups=")
group = PROCINFO["group" i]
printf("%d", group)
pw = getgrgid(group)
if (pw != "")
pr_first_field(pw)
if (("group" (i+1)) in PROCINFO)
printf(",")
}
print ""
}
function pr_first_field(str, a)
{
split(str, a, ":")
printf("(%s)", a[1])
}
|
